﻿///////////////////////////////////////////////////
//			     	                 //
// PoD-Medikit:		v1.0 	           	 //
// Written by:		*InterCom, By_Moderator Expensive//
// Date written:	25.10.2010               //
// Last Update:		30.11.2010               //
//			                         //
// Description:				         //
// Player can restore HP with Medikits and share //
// them to other teammates.			 //
//						 //
// Installation:				 //
// Edit "config.cfg" and move the pod_medikit    //
// folder to: cstrike/addons/eventscripts  	 //
// After that put "es_xload pod_medikit" in your //
// Autoexec.cfg and restart your server or load  //
// the addon with rcon acces.			 //
//						 //
// Have Fun!					 //
//						 //
// www.CssGermanTutorials.de			 //
// www.Counterstrike-Tutorials.de		 //
//						 //
///////////////////////////////////////////////////
block load
{
	es_xset pod_medikit_version v1.0
 	es_makepublic pod_medikit_version
	es_regsaycmd !help pod_medikit/hilfe "Help"
	es_regsaycmd !kits pod_medikit/kits "Number Of Medikits"
	es_regsaycmd !medikit pod_medikit/medikit "Use Medikit"
	es_regsaycmd !share pod_medikit/share "Share Your Medikit"

	es_xset medikit_amount 1
	es_xset medikit_hp 60
	es_xset medikit_share 1
	es_xset medikit_maxhp 100
	es_xset medikit_sound_use 1
	es_xset medikit_sound_share 1
	es_xset medikit_advert 1
	es_xset medikit_advert_delay 120

	es_xmexec ../addons/eventscripts/pod_medikit/config.cfg

	downloadable sound/pod_medikit/medikit_use.wav
	downloadable sound/pod_medikit/medikit_share.wav

	if (server_var(medikit_advert) == 1) then es_delayed server_var(medikit_advert_delay) es_xdoblock pod_medikit/advert

	es_msg #multi #green[PoD-Medikit]#lightgreen server_var(pod_medikit_version) #default- Loaded!
}

block unload
{
	clientcmd delete say !help
	clientcmd delete say !kits
	clientcmd delete say !medikit
	clientcmd delete say !share

	es_msg #multi #green[PoD-Medikit]#lightgreen server_var(pod_medikit_version) #default- Unloaded!
}

block advert
{
	if (server_var(medikit_advert) == 1) then es_delayed server_var(medikit_advert_delay) es_xdoblock pod_medikit/advert
	es_xmsg #multi #green[PoD-Medikit] #defaultType #lightgreen!help #defaultto get information about Medikits!
}

event es_map_start
{
	downloadable sound/pod_medikit/medikit_use.wav
	downloadable sound/pod_medikit/medikit_share.wav
	if (server_var(medikit_advert) == 1) then es_delayed server_var(medikit_advert_delay) es_xdoblock pod_medikit/advert
}

event player_spawn
{
	es playervar set event_var(userid) medikits server_var(medikit_amount)
}

block kits
{
	es_xset user 0
	es_getcmduserid user
	es_xset getmedikits 0
	es playervar get getmedikits server_var(user) medikits
	if (server_var(getmedikits) == 1) do
	{
		es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou have:#lightgreen server_var(getmedikits) Medikit left
	}
	else do
	{
		es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou have:#lightgreen server_var(getmedikits) Medikits left
	}
}

block hilfe
{
	es_xset user 0
	es_getcmduserid user
	es_tell server_var(user) #multi #green[PoD-Medikit] #defaultCommands:
	es_tell server_var(user) #multi #green[PoD-Medikit] #lightgreen!Kits #default= Number of Medikits
	es_tell server_var(user) #multi #green[PoD-Medikit] #lightgreen!Medikit #default= Restores server_var(medikit_hp) HP
	es_tell server_var(user) #multi #green[PoD-Medikit] #lightgreen!Share X #default= Give your teammate 1 Kit
	es_tell server_var(user) #multi #green[PoD-Medikit] #default(#greenX#default = #greenUserid#default or #greenPart of Name#default)
}

block medikit
{
	es_xset user 0
	es_getcmduserid user
	es_xset getmedikits 0
	es playervar get getmedikits server_var(user) medikits
	if (server_var(getmedikits) > 0) do
	{
		es_xset deadcheck 0
		es playerget isdead deadcheck server_var(user)
		if (server_var(deadcheck) == 0) do
		{
			es_xset hpcheck_before 0
			es playerget health hpcheck_before server_var(user)
			if (server_var(hpcheck_before) < server_var(medikit_maxhp)) do
			{
				if (server_var(medikit_sound_use) == 1) then es_playsound server_var(user) pod_medikit/medikit_use.wav 1.0
				es playerset healthadd server_var(user) server_var(medikit_hp)
				es_xset hpcheck_after 0
				es playerget health hpcheck_after server_var(user)
				if (server_var(hpcheck_after) > server_var(medikit_maxhp)) then es playerset health server_var(user) server_var(medikit_maxhp)
				if (server_var(hpcheck_after) > server_var(medikit_maxhp)) then es_xset hpcheck_after server_var(medikit_maxhp)
				es_math getmedikits - 1
				es playervar set server_var(user) medikits server_var(getmedikits)
				es_math hpcheck_after - server_var(hpcheck_before)
				es_tell server_var(user) #multi #green[PoD-Medikit] #defaultRestored#lightgreen server_var(hpcheck_after) HP
				if (server_var(getmedikits) == 1) do
				{
					es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou have:#lightgreen server_var(getmedikits) Medikit left
				}
				else do
				{
					es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou have:#lightgreen server_var(getmedikits) Medikits left
				}
			}
			else do
			{
				es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou have already full health!
			}
		}
		else do
		{
			es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou are dead!
		}
	}
	else do
	{
		es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou have no more medikit!
	}
}

block share
{
	if (server_var(medikit_share) == 1) do
	{
	es_xset user 0
	es_getcmduserid user
	es_xset user_mate_name 0
	es_getargs user_mate_name 0
	es_xset user_mate 0
	es_getuserid user_mate server_var(user_mate_name)
	if (server_var(user_mate) == 0) do
	{
		//Syntax Error
		es_tell server_var(user) #multi #green[PoD-Medikit] #defaultSyntax Error!
		es_tell server_var(user) #multi #green[PoD-Medikit] #defaultSyntax: #green!Share [userid | name]
	}
	if (server_var(user_mate) > 0) do
	{
		if (server_var(user_mate) == server_var(user)) do
		{
			//Eigene ID
			es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou can not give yourself one!
		}
		else do
		{
			//Fremde ID	
			es_xset deadcheck 0
			es playerget isdead deadcheck server_var(user)
			if (server_var(deadcheck) == 0) do
			{
				es_xset teamcheck 0
				es_getplayerteam teamcheck server_var(user)
				es_xset teamcheck_mate 0
				es_getplayerteam teamcheck_mate server_var(user_mate)
				if (server_var(teamcheck) == server_var(teamcheck_mate)) do
				{
					es_xset deadcheck2 0
					es playerget isdead deadcheck2 server_var(user_mate)
					if (server_var(deadcheck2) == 0) do
					{
						es_xset getmedikits 0
						es playervar get getmedikits server_var(user) medikits
						if (server_var(getmedikits) > 0) do
						{
							es_math getmedikits - 1
							es playervar set server_var(user) medikits server_var(getmedikits)
							es_xset getmedikits 0
							es playervar get getmedikits server_var(user_mate) medikits
							es_math getmedikits + 1
							es playervar set server_var(user_mate) medikits server_var(getmedikits)
							es_xset name 0
							es_getplayername name server_var(user_mate)
							es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou gave#lightgreen server_var(name) #defaulta medikit!
							es_xset name 0
							es_getplayername name server_var(user)
							es_tell server_var(user_mate) #multi #green[PoD-Medikit] #defaultYou received a medikit from#lightgreen server_var(name) #default!
							if (server_var(medikit_sound_share) == 1) then es_playsound server_var(user_mate) pod_medikit/medikit_share.wav 1.0
						}
						else do
						{
							es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou have no more medikits!
						}
					}
					else do
					{
						es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYour teammate is dead!
					}
				}
				else do
				{
					es_tell server_var(user) #multi #green[PoD-Medikit] #defaultTarget have to be a teammate!
				}
			}
			else do
			{
				es_tell server_var(user) #multi #green[PoD-Medikit] #defaultYou are dead!
			}
		}
	}
	}
}